;csaAmplification853

;csaAmplification853 sequence

;Avance II+ version
;parameters: 
;p3 : 1H 90 degree pulse length at power level pl22
;pl22 : power level for 1H 90 degree pulse
;p15 : contact time
;pl1 : X power level for CP
;sp0 : H power level for CP
;p1 :13C 90 degree pulse length at power level pl11
;p2 : 13C 180 degree pulse length at power level pl11
;pl11 : power level for 13C pulses
;pl2 : =120dB, not used
;pl12 : decoupling power level
;pl13 : fslg decoupling power level
;d1 : relaxation delay
;cnst21 : on resonance, usually = 0
;pcpd2 : pulse length for decoupling sequence
;cpdprg2 : decoupling (cw, tppm etc.) 
;spnam0 : shape for CP
;zgoptns : -Dfslg, -Dlacq, or blank

;$COMMENT=CSA Amplification
;$CLASS=Solids
;$DIM=2D
;$TYPE=CSA measurement
;$SUBTYPE=Sideband
;$OWNER=JJT
prosol relations=<solids_cp>

#include <Avancesolids.incl>

#ifdef fslg
#include <lgcalc.incl>
;cnst20 : RF field achieved at pl13
;cnst21 : on resonance, usually = 0
;cnst22 : positive LG offset
;cnst23 : negative LG offset
;cnst24 : additional LG-offset
#endif /* fslg */
;cnst11 : to adjust t=0 for acquisition, if digmod = baseopt
"acqt0=1u*cnst11"

"d0=0.1u"
"in0=inf1"

"d21=0.25s/cnst31-(p2/2.0)"
"d22=0.75s/cnst31-p2"
"d23=0.5s/cnst31-p2"
"d24=d23"
"d25=d22"
"d26=d21"
"d27=d21-de"

1 ze

2 d1 do:f2
#include <p15_prot.incl>	
			;make sure p15 does not exceed 10 msec	
			;let supervisor change this pulseprogram if 
			;more is needed
#ifndef lacq		
			;disable protection file for long acquisition change decoupling power !!! or you risk probe damage
			;if you set the label lacq (ZGOPTNS -Dlacq), the protection is disabled

#include <aq_prot.incl>	
			;allows max. 50 msec acquisition time, supervisor
			;may change  to max. 1s at less than 5 % duty cycle
			;and reduced decoupling field
#endif

  1u fq=cnst21:f2
  (p3 pl22 ph1):f2
  (p15 pl1 ph2):f1 (p15:sp0 ph0):f2
  d21 cpds2:f2  ;pl12 is used here with tppm, pl13 with cwlg, cwlgs
  (p2 pl11 ph3):f1
  d22
  (p2 pl11 ph4):f1
  d23
  (p2 pl11 ph5):f1
  d24
  (p2 pl11 ph4):f1
  d25
  (p2 pl11 ph3):f1
  d26		
  (p1 pl11 ph6):f1
  d0 do:f2
  (p1 pl11 ph7):f1
  d21 cpds2:f2  ;pl12 is used here with tppm, pl13 with cwlg, cwlgs
  (p2 pl11 ph13):f1
  d22
  (p2 pl11 ph14):f1
  d23
  (p2 pl11 ph15):f1
  d24
  (p2 pl11 ph14):f1
  d25
  (p2 pl11 ph13):f1
  d27		
  go=2 ph31
  1m do:f2
  d1 mc #0 to 2 F1QF(id0) 
HaltAcqu, 1m
exit

ph0= 1
ph1= 0 2
ph2= 0 0 2 2

ph3= (12) 0 0 0 0 6 6 6 6
ph4= (12) 11 11 11 11 5 5 5 5
ph5= (12) 1 1 1 1 7 7 7 7

ph6= {1}*8 {2}*8
ph7= {0}*16 {2}*16

ph13= (12) {0}*32 {6}*32
ph14= (12) {11}*32 {5}*32
ph15= (12) {1}*32 {7}*32

ph31= 0 2 2 0 0 2 2 0 1 3 3 1 1 3 3 1 2 0 0 2 2 0 0 2 3 1 1 3 3 1 1 3